X-Plane DIY Home Made Cockpit Panel

#include <Bounce.h>
#include <Encoder.h>
#include <DogLcd.h>

// hardware objects, for accessing the buttons, rotary encoder and LCD
//
Bounce buttonUp = Bounce(3, 5);      // Pushbutton on pin 3, 5ms debounce
Bounce buttonDown = Bounce(4, 5);    // Pushbutton on pin 4, 5ms debounce
Encoder wheel = Encoder(5, 6);       // Rotary Encoder on pin 5 and 6
DogLcd lcd = DogLcd(10, 9, 7, 8);    // DogM LCD on pins 7, 8, 9, 10

  // if there's no user activity for 2 seconds, send the NavFineUp.
  // admittedly this is not very useful, but it's meant to demonstrate
  // possibility of automated actions in addition to driving everything
  // directly from physical user inputs.
  if (inactivityTimeout > 2000) {
    NavFineUp.once();
    inactivityTimeout = 0;
  }

#include <Bounce.h>
#include <Encoder.h>
#include <DogLcd.h>

// hardware objects, for accessing the buttons, rotary encoder and LCD
//
Bounce buttonUp = Bounce(3, 5);      // Pushbutton on pin 3, 5ms debounce
Bounce buttonDown = Bounce(4, 5);    // Pushbutton on pin 4, 5ms debounce
Encoder wheel = Encoder(5, 6);       // Rotary Encoder on pin 5 and 6
DogLcd lcd = DogLcd(10, 9, 7, 8);    // DogM LCD on pins 7, 8, 9, 10

// X-Plane objects, 3 command refs and 1 data ref
FlightSimCommand NavCoarseUp;
FlightSimCommand NavCoarseDown;
FlightSimCommand NavFineUp;
FlightSimInteger NavFrequencyHz;

// 変数
long encoder_prev=0;    // 回転位置の変化を検出する
elapsedMillis inactivityTimeout;   // 無活動タイムアウト


// setup runs once, when Teensy boots.
//
void setup() {
  // initialize all hardware
  pinMode(3, INPUT_PULLUP);  // input pullup mode allows connecting
  pinMode(4, INPUT_PULLUP);  // buttons and switches from the pins
  pinMode(5, INPUT_PULLUP);  // to ground, and the chip provide the
  pinMode(6, INPUT_PULLUP);  // required pullup resistor :-)
  lcd.begin(DOG_LCD_M162);
  lcd.print("nav1:");

  // configure the X-Plane variables
  NavCoarseUp = XPlaneRef("sim/radios/actv_nav1_coarse_up");     //プッシュボタン用
  NavCoarseDown = XPlaneRef("sim/radios/actv_nav1_coarse_down");       //プッシュボタン用
  NavFineUp = XPlaneRef("sim/radios/actv_nav1_fine_up");              //自動アップ用
  NavFrequencyHz = XPlaneRef("sim/cockpit2/radios/actuators/nav1_frequency_hz");      //ロータリーエンコーダ用
  NavFrequencyHz.onChange(update_lcd);  // update the LCD when X-Plane changes
}

// loop runs repetitively, as long as Teensy is powered up
//
void loop() {
  // normally the first step in loop() should update from X-Plane
  FlightSim.update();

  // ロータリーエンコーダを読む、それが変わった場合には、NavFrequencyHzに書き込む
  long enc = wheel.read();    // wheelはエンコーダピンを指し、それを読むという意味。longは32ビットの整数を格納するencを宣言
  if (enc != encoder_prev) {    // enc と encoder_prevは等しくない場合
    NavFrequencyHz = NavFrequencyHz + (enc - encoder_prev); //NavFrequencyHzの値を読み込んだピンの値にプラスする
    encoder_prev = enc;
    update_lcd(NavFrequencyHz); // update_lcdでNavFrequencyHzを更新する
    inactivityTimeout = 0;   // 無活動タイムアウトをリセット
  }

  // read the pushbuttons, and send X-Plane commands when they're pressed
  //
  buttonUp.update();
  buttonDown.update();
  if (buttonUp.fallingEdge()) {
    NavCoarseUp = 1;
    inactivityTimeout = 0;
  }
  if (buttonUp.risingEdge()) {
    NavCoarseUp = 0;
  }
  if (buttonDown.fallingEdge()) {
    NavCoarseDown = 1;
    inactivityTimeout = 0;
  }
  if (buttonDown.risingEdge()) {
    NavCoarseDown = 0;
  }

  // if there's no user activity for 2 seconds, send the NavFineUp.
  // admittedly this is not very useful, but it's meant to demonstrate
  // possibility of automated actions in addition to driving everything
  // directly from physical user inputs.
  if (inactivityTimeout > 2000) {
    NavFineUp.once();
    inactivityTimeout = 0;
  }
}

// write a number onto the LCD, first row, starting at 6th column
void update_lcd(long val)
{
  lcd.setCursor(6, 0);
  lcd.print(val);
  lcd.print("  ");
}